該教程顯示出不同的方式從Excel中生日。您將學(xué)習(xí)一些公式，以計算年齡為多年的年齡，在今天的日期或特定日期中以年，幾個月和幾天的形式獲得確切的年齡。

沒有特殊的功能可以計算Excel年齡，但是有幾種不同的方式將出生日期轉(zhuǎn)換為年齡。本教程將解釋每種方式的優(yōu)點和缺點，并顯示如何在Excel中制定完美的年齡計算公式并調(diào)整以解決某些特定任務(wù)。

如何計算出excel的出生日期的年齡

在日常生活中，“您幾歲？ ”通常意味著答案，表明您還活著多少年。在Microsoft Excel中，您可以制作一個公式來計算幾個月，幾天，小時甚至分鐘的精確年齡。但是，讓我們成為傳統(tǒng)，并學(xué)習(xí)如何在幾年內(nèi)從DOB中計算年齡。

年齡的基本Excel公式

您通常如何找出某人的年齡？只需從當(dāng)前日期減去出生日期即可。這種常規(guī)的年齡公式也可以在Excel中使用。

假設(shè)出生日期在細(xì)胞B2中，那么計算年齡的公式如下：

=(TODAY()-B2)/365

公式的第一部分（今天（） - b2）返回當(dāng)前日期和出生日期之間的差異，然后將該數(shù)字除以365，以獲取年數(shù)。

該公式是明顯且易于記住的，但是有一個很小的問題。在大多數(shù)情況下，它返回一個小數(shù)號，如下面的屏幕截圖所示。

要顯示完整年的數(shù)量，請使用INT功能將小數(shù)點舍入到最近的整數(shù)：

=INT((TODAY()-B2)/365)

缺點：在Excel中使用此年齡公式會產(chǎn)生相當(dāng)準(zhǔn)確的結(jié)果，但并非完美無缺。在大多數(shù)情況下，一年中平均數(shù)量的平均天數(shù)可以正常工作，但有時會使年齡錯誤。例如，如果某人于2月29日出生，今天是2月28日，則該公式將使一個人有一天。

作為替代方案，您可以除以365.25而不是365，因為每四年級有366天。但是，這種方法也不是完美的。例如，如果您正在計算尚未過跨越一年的孩子的年齡，則除以365.25會產(chǎn)生錯誤的結(jié)果。

總體而言，從當(dāng)前日期中減去出生日期在正常生活中效果很好，但不是Excel的理想方法。在本教程中，您將學(xué)習(xí)一些特殊功能，這些功能不管年度如何，都可以無限計算年齡。

通過年齡段功能從出生日期開始計算年齡

將DOB轉(zhuǎn)換為Excel年齡的一種更可靠的方法是使用返回一年部分的年度FRAC功能，即在兩個日期之間的整天數(shù)量。

年度FRAC函數(shù)的語法如下：

前兩個論點很明顯，幾乎不需要任何其他解釋。基礎(chǔ)是一個可選的論點，它定義了使用的日計數(shù)基礎(chǔ)。

為了制定完美的年齡公式，請為年度FRAC函數(shù)提供以下值：

• start_date-出生日期。
• end_date-今天（）函數(shù)返回今天的日期。
• 基礎(chǔ)- 使用基礎(chǔ)1告訴Excel將實際天數(shù)除以每年的實際天數(shù)。

考慮到上述內(nèi)容，從出生日期開始計算年齡的Excel公式如下：

假設(shè)生日在細(xì)胞B2中，則該公式采用以下形狀：

=YEARFRAC(B2, TODAY(), 1)

像上一個示例一樣，年度FRAC函數(shù)的結(jié)果也是十進(jìn)制數(shù)字。要解決此問題，請在最后一個參數(shù)中使用0次數(shù)，因為您不需要小數(shù)點。

因此，這是計算Excel年齡的改進(jìn)的年度FRAC公式：

=ROUNDDOWN(YEARFRAC(B2, TODAY(), 1), 0)

用日期計算Excel的年齡

將出生日期轉(zhuǎn)換為Excel年齡的另一種方法是使用日期功能：

此功能可以返回各個時間單元中兩個日期之間的差異，例如年，幾個月和幾天，具體取決于您在單位參數(shù)中提供的價值：

• Y-返回開始日期和結(jié)束日期之間的完整年數(shù)。
• M-返回日期之間的完整月數(shù)。
• D-返回兩個日期之間的天數(shù)。
• YM-返回幾個月，忽略天數(shù)。
• MD-返回幾天的差異，忽略了幾個月和幾年。
• YD-返回幾天的差異，忽略了幾年。

由于我們的目標(biāo)是計算年齡，因此我們使用“ Y”單元：

在此示例中，DOB在單元格B2中，您以年齡公式引用此單元格：

=DATEDIF(B2, TODAY(), "y")

在這種情況下，不需要額外的舍入功能，因為具有“ Y”單元的日期公式可以計算全年數(shù)量：

如何在幾年，幾個月和幾天內(nèi)從生日開始年齡

正如您剛剛看到的那樣，將年齡計算為該人壽命的全年數(shù)量很容易，但這并不總是足夠的。如果您想知道確切的年齡，即某人的出生日期和當(dāng)前日期之間有多少年，幾個月和幾天，請寫3個不同的日期功能：

1. 要獲得年數(shù)： =DATEDIF(B2, TODAY(), "Y")
2. 要獲取月數(shù)： =DATEDIF(B2, TODAY(), "YM")
3. 要獲取天數(shù)： =DATEDIF(B2,TODAY(),"MD")

其中B2是出生日期。

然后，將上述功能加入單個公式，例如：

=DATEDIF(B2,TODAY(),"Y") & DATEDIF(B2,TODAY(),"YM") & DATEDIF(B2,TODAY(),"MD")

上面的公式返回以單個文本字符串連接的3個數(shù)字（年，月和天），如下屏幕截圖所示：

沒什么意義，呃？為了使結(jié)果更有意義，請與逗號分開數(shù)字并定義每個值的含義：

=DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"

結(jié)果現(xiàn)在看起來好多了：

該公式效果很好，但是您可以通過隱藏零值來進(jìn)一步改進(jìn)它。為此，添加3個如果檢查0的語句，則每個日期為一個：

=IF(DATEDIF(B2, TODAY(),"y")=0,"",DATEDIF(B2, TODAY(),"y")&" years, ")& IF(DATEDIF(B2, TODAY(),"ym")=0,"",DATEDIF(B2, TODAY(),"ym")&" months, ")& IF(DATEDIF(B2, TODAY(),"md")=0,"",DATEDIF(B2, TODAY(),"md")&" days")

以下屏幕截圖證明了動作中最終的Excel年齡公式 - 它在幾年，月和天中返回年齡，僅顯示非零值：

提示。如果您正在尋找一個excel公式來計算年齡的年齡，請采用上述公式，然后刪除計算天數(shù)的（日期（））塊的最后一個公式。

特定公式以計算Excel年齡

在大多數(shù)情況下，上面討論的通用年齡計算公式效果很好。但是，在某些情況下，您可能需要一些非常具體的東西。當(dāng)然，不可能涵蓋每種情況，但是以下示例將為您提供一些有關(guān)如何根據(jù)您的特定任務(wù)調(diào)整年齡公式的想法。

如何計算Excel中特定日期的年齡

如果您想在某個日期了解某人的年齡，請使用上面討論的日期年齡公式，但用特定日期替換2 ^nd參數(shù)中的today（）函數(shù)。

假設(shè)出生日期在B1中，以下公式將截至2020年1月1日返回年齡：

=DATEDIF(B1, "1/1/2020","Y") & " Years, " & DATEDIF(B1, "1/1/2020","YM") & " Months, " & DATEDIF(B1, "1/1/2020", "MD") & " Days"

為了使您的年齡公式更加靈活，您可以在某個單元格中輸入日期，并在公式中引用該單元格：

=DATEDIF(B1, B2,"Y") & " Years, "& DATEDIF(B1,B2,"YM") & " Months, "&DATEDIF(B1,B2, "MD") & " Days"

其中B1是DOB，而B2是您要計算年齡的日期。

計算一年的年齡

在未定義要計算的完整日期的情況下，此公式派上用場，您只知道一年。

假設(shè)您正在使用醫(yī)療數(shù)據(jù)庫，而您的目標(biāo)是在接受最后一次完整的醫(yī)學(xué)檢查時找出患者的年齡。

假設(shè)出生日期是從第3行開始的B列，最后一次醫(yī)學(xué)檢查的年份是在C列中，則年齡計算公式如下：

=DATEDIF(B3,DATE(C3, 1, 1),"y")

由于未定義醫(yī)學(xué)檢查的確切日期，因此您將日期函數(shù)使用任意日期和月參數(shù)，例如日期（C3，1，1）。

日期函數(shù)從單元B3中提取年份，使用您提供的月份和日號（在此示例中為1-JAN），并將該日期傳遞給日期。結(jié)果，截至特定年的1月1日，您會獲得患者的年齡：

找出一個人達(dá)到N年齡的日期

假設(shè)您的朋友出生于1978年3月8日。通常，您只會在該人的生日中增加50年。在Excel中，您使用日期函數(shù)進(jìn)行相同的操作：

=DATE(YEAR(B2) 50, MONTH(B2), DAY(B2))

其中B2是出生日期。

您可以參考用戶可以輸入任何數(shù)年的特定單元格（在下面的屏幕截圖中）：

計算不同細(xì)胞的日，月和年的年齡

當(dāng)生日分為3個不同的細(xì)胞（例如B3，C3的月份，D3中的一天）時，您可以以這種方式計算年齡：

• 通過使用日期和日期功能來獲取出生日期： DATE(B3,MONTH(DATEVALUE(C3&"1")),D3)
• Embed the above formula into DATEDIF to calculate age from date of birth in years, months, and days: =DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "y") & " Years, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3),TODAY(), "ym") & " Months, "& DATEDIF(DATE(B3, MONTH(DATEVALUE(C3&"1")), D3), TODAY(), "md") & " Days"

  

有關(guān)計算日期之前/之后天數(shù)的更多示例，請查看如何計算以來或直到Excel中的日期。

Excel中的年齡計算器

如果您想在Excel中擁有自己的年齡計算器，則可以使用下面解釋的一些不同的日期公式來制作一個。如果您不想重新發(fā)明輪子，則可以使用我們Excel專業(yè)人員創(chuàng)建的年齡計算器。

如何在Excel中創(chuàng)建年齡計算器

現(xiàn)在您知道如何在Excel中制作一個年齡公式，可以構(gòu)建自定義年齡計算器，例如：

筆記。要查看嵌入式工作簿，請允許營銷餅干。

您在上面看到的是嵌入式excel在線表，因此請隨時進(jìn)入相應(yīng)的單元格中的生日，您會稍后才能達(dá)到年齡。

計算器使用以下公式根據(jù)細(xì)胞A3和今天的日期根據(jù)出生日期來計算年齡。

• B5中的公式計算年度，月和天的年齡： =DATEDIF(B2,TODAY(),"Y") & " Years, " & DATEDIF(B2,TODAY(),"YM") & " Months, " & DATEDIF(B2,TODAY(),"MD") & " Days"
• B6中的公式計算幾個月的年齡： =DATEDIF($B$3,TODAY(),"m")
• B7中的公式在天數(shù)中計算年齡： =DATEDIF($B$3,TODAY(),"d")

如果您在Excel表單控件方面有一定的經(jīng)驗，則可以在特定日期添加一個選項以計算年齡，如以下屏幕截圖所示：

為此，添加幾個選項按鈕（開發(fā)人員選項卡>插入>表單控件>選項按鈕），然后將它們鏈接到某些單元格。然后，編寫一個if/netatedif公式，以在今天的日期或用戶指定的日期中年齡。

該公式可與以下邏輯合作：

• 如果選擇了今天的日期選項框，則值1將出現(xiàn)在鏈接的單元格（i5）中，并且年齡公式根據(jù)今天的日期計算： IF($I$5=1, DATEDIF($B$3,TODAY(),"Y") & " Years, " & DATEDIF($B$3,TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days")
• If the Specific date option button is selected AND a date is entered in cell B7, age is calculated at the specified date: IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

最后，將上述功能相互嵌套，您將獲得完整的年齡計算公式（在B9中）：

=IF($I$5=1, DATEDIF($B$3, TODAY(), "Y") & " Years, " & DATEDIF($B$3, TODAY(), "YM") & " Months, " & DATEDIF($B$3, TODAY(), "MD") & " Days", IF(ISNUMBER($B$7), DATEDIF($B$3, $B$7,"Y") & " Years, " & DATEDIF($B$3, $B$7,"YM") & " Months, " & DATEDIF($B$3, $B$7,"MD") & " Days", ""))

B10和B11中的公式具有相同的邏輯。當(dāng)然，它們要簡單得多，因為它們僅包含一個日期的功能，分別作為完整的月份或幾天的數(shù)量返回年齡。

要了解詳細(xì)信息，我邀請您下載此Excel年齡計算器，并研究單元格B9：B11中的公式。

下載Excel的年齡計算器

Excel的現(xiàn)成年齡計算器

我們的Ultimate Suite的用戶不必費心在Excel中制作自己的年齡計算器 - 只需單擊幾下：

1. 選擇要插入年齡公式的單元格，轉(zhuǎn)到“ ablebits工具”選項卡>日期和時間組，然后單擊日期和時間向?qū)?/b>按鈕。

   

2. 日期和時間向?qū)㈤_始，您直接轉(zhuǎn)到“年齡”選項卡。
3. 在“年齡”選項卡上，您有3件事可以指定：
   • 以MM/DD/YYYY格式出生的數(shù)據(jù)作為細(xì)胞參考或日期。
   • 今天的日期或特定日期。
   • 選擇是否計算幾天，幾個月，年或確切年齡的年齡。
4. 單擊插入公式按鈕。